Помощь Регистрация
Показано с 1 по 4 из 4
  1. #1
    Moderator Аватар для Mazzay
    Регистрация
    21.02.2007
    Пол
    Пол: Мужской
    Авто
    BMW (BeMyWife)
    Сообщений
    56 579
    Благодарности

    Question Как зацепить аргументы из коммандной строки в VB-скрипте?

    Возможно ли это вообще?
    И если да, то как?

  2. #2

    Регистрация
    20.02.2006
    Сообщений
    202
    Благодарности
    Цитата Сообщение от Mazzay Посмотреть сообщение
    Возможно ли это вообще?
    И если да, то как?
    Код:
     '********************************************************************
    ' Имя: Args.vbs
    ' Язык: VBScript
    ' Описание: Работа с аргументами запущенного сценария
    '********************************************************************
    Option Explicit
    
    Dim i,Arg,objArgs,s,objNamedArgs,objUnnamedArgs  ' Объявляем переменные
    
    Set objArgs = WScript.Arguments  ' Создаем объект WshArguments
    ' Определяем общее количество аргументов
    s="Всего аргументов: " & objArgs.Count() & vbCrLf
    For Each Arg In objArgs
      s=s & Arg & vbCrLf  ' Формируем строки со значениями аргументов
    Next
    
    Set objUnnamedArgs=objArgs.Unnamed  ' Создаем объект WshUnnamed
    ' Определяем количество безымянных аргументов
    s=s & vbCrLf & "Безымянных аргументов: " & objUnnamedArgs.length & vbCrLf
    For Each Arg In objUnnamedArgs
      ' Формируем строки со значениями безымянных аргументов
      s=s & Arg & vbCrLf
    Next
    
    Set objNamedArgs=objArgs.Named  ' Создаем объект WshNamed
    ' Определяем количество именных аргументов
    s=s & vbCrLf & "Именных аргументов: " & objNamedArgs.Length & vbCrLf
    ' Проверяем, существует ли аргумент /Имя:
    If objNamedArgs.Exists("Имя") Then
      s=s & objNamedArgs("Имя") & vbCrLf
    End If
    ' Проверяем, существует ли аргумент /Comp:
    If objNamedArgs.Exists("Comp") Then
      s=s & objNamedArgs("Comp") & vbCrLf
    End If
    
    WScript.Echo s   ' Выводим сформированные строки
    '*************  Конец *********************************************
    оно?

  3. #3
    Moderator Аватар для Mazzay
    Регистрация
    21.02.2007
    Пол
    Пол: Мужской
    Авто
    BMW (BeMyWife)
    Сообщений
    56 579
    Благодарности
    Оно. Спасибо! Просто в моём хэлпе про это нет ничего.

  4. #4

    Регистрация
    20.02.2006
    Сообщений
    202
    Благодарности
    гугль - найдется все

Похожие темы
  1. Ответов: 7
    Последнее сообщение: 19.08.2008, 15:09
  2. Как попроще доставить из Москвы большие коробки?
    от And626GE92 в разделе Полезно. Интересно. Познавательно
    Ответов: 3
    Последнее сообщение: 07.05.2008, 19:30
  3. Как попроще доставить из Москвы большие коробки?
    от And626GE92 в разделе Автомобильный
    Ответов: 1
    Последнее сообщение: 07.05.2008, 06:51
  4. как пригнать машину из Тольяти
    от Черт в разделе Автомобили
    Ответов: 1
    Последнее сообщение: 04.08.2007, 23:08
  5. Как привезти мотор из Москвы?
    от ice в разделе Автомобильный
    Ответов: 10
    Последнее сообщение: 01.06.2005, 02:00
Ваши права
  • Вы не можете создавать новые темы
  • Вы не можете отвечать в темах
  • Вы не можете прикреплять вложения
  • Вы не можете редактировать свои сообщения
  •